#!/usr/bin/gnuplot

print "$OUT";

set term post eps enh color solid "Helvetica" 18
set out "animace/$OUT.eps"
set size 0.8,1.2

#set term png small
#set out "animace/$OUT.png"

logT_Sun = log10(5780.)	# K

set xl "log [{/Helvetica-Oblique T}_{surf}]_{K}"
set yl "log {/Helvetica-Oblique L}/{/Helvetica-Oblique L}_{Sun}"

set xr [4.8:3.2]
y1=-6
y2=8
set yr [y1:y2]

set nokey
set zeroaxis
set lmargin 5.9
set rmargin 1.4
set bmargin 3.1
set tmargin 1.0

pt=7
ps=1.5
set style line 1 lt 1 pt pt ps ps
set style line 2 lt 6
set style line 3 lt 1 pt pt ps ps
set style line 4 lt 1
set style line 5 lt 8 lw 3

set nolabel
load "HR_diagram_GRID.lab"
load "sptyp_index.lab"
set label "  ZAMS" at 0.343232324055E+01, -.306222556372E+01 left font "Helvetica,14" front
set label "{/Helvetica-Oblique T}_{Sun}" at first logT_Sun, graph 0.08 center font "Helvetica,14" front
set label "{/Helvetica-BoldOblique t} = $MYRGYR" at graph 0.2,0.15 center font "Helvetica-Bold,18" front textcolor lt $TC

p "star_data/ZAMS.data" u 4:3 w l ls 5,\
  "<./time2.awk $TIME M*_*/basics.log"         u 5:3 w l ls 2,\
  "<./time1i.awk $TIME M*_*/basics.log"         u 5:3 w p ls 1,\
  "<./time2.awk $TIME M004.0_Z0.02/basics.log" u 5:3 w l ls 4,\
  "vline.dat" u ($1*logT_Sun):(y1+0.06*$2*(y2-y1)) w l lt 0
#pa -1

#  "<./time1.awk $TIME M004.0_Z0.02/basics.log" u 5:3 w p ls 3,\

########################################################################

